db28818476
Prior to this patch, WPD was not acting on relative-vtables in C++. This involves teaching WPD about these things: - llvm.load.relative which is how relative-vtables are indexed (instead of GEP) - dso_local_equivalent which is used in the vtable itself when taking the offset between a virtual function and vtable - Update llvm/test/ThinLTO/X86/devirt.ll to use opaque pointers and add equivalent tests for RV Differential Revision: https://reviews.llvm.org/D134320
43 lines
1.1 KiB
LLVM
43 lines
1.1 KiB
LLVM
; RUN: opt -S -passes=wholeprogramdevirt -whole-program-visibility %s | FileCheck %s
|
|
|
|
target datalayout = "e-p:64:64"
|
|
target triple = "x86_64-unknown-linux-gnu"
|
|
|
|
@vt = constant ptr @vf, !type !0
|
|
|
|
define void @vf(ptr %this) {
|
|
ret void
|
|
}
|
|
|
|
; CHECK: define void @call
|
|
define void @call(ptr %obj) {
|
|
%vtable = load ptr, ptr %obj
|
|
%p = call i1 @llvm.type.test(ptr %vtable, metadata !"typeid")
|
|
call void @llvm.assume(i1 %p)
|
|
%fptr = load ptr, ptr %vtable
|
|
; CHECK: call void @vf(
|
|
call void %fptr(ptr %obj)
|
|
ret void
|
|
}
|
|
|
|
@vt2 = constant i32 trunc (i64 sub (i64 ptrtoint (ptr dso_local_equivalent @vf to i64), i64 ptrtoint (ptr @vt2 to i64)) to i32), !type !1
|
|
|
|
declare ptr @llvm.load.relative.i32(ptr, i32)
|
|
|
|
; CHECK: define void @call2
|
|
define void @call2(ptr %obj) {
|
|
%vtable = load ptr, ptr %obj
|
|
%p = call i1 @llvm.type.test(ptr %vtable, metadata !"typeid2")
|
|
call void @llvm.assume(i1 %p)
|
|
%fptr = call ptr @llvm.load.relative.i32(ptr %vtable, i32 0)
|
|
; CHECK: call void @vf(
|
|
call void %fptr(ptr %obj)
|
|
ret void
|
|
}
|
|
|
|
declare i1 @llvm.type.test(ptr, metadata)
|
|
declare void @llvm.assume(i1)
|
|
|
|
!0 = !{i32 0, !"typeid"}
|
|
!1 = !{i32 0, !"typeid2"}
|