a97f62837f
The `dso_local_equivalent` constant is a wrapper for functions that represents a value which is functionally equivalent to the global passed to this. That is, if this accepts a function, calling this constant should have the same effects as calling the function directly. This could be a direct reference to the function, the `@plt` modifier on X86/AArch64, a thunk, or anything that's equivalent to the resolved function as a call target. When lowered, the returned address must have a constant offset at link time from some other symbol defined within the same binary. The address of this value is also insignificant. The name is leveraged from `dso_local` where use of a function or variable is resolved to a symbol in the same linkage unit. In this patch: - Addition of `dso_local_equivalent` and handling it - Update Constant::needsRelocation() to strip constant inbound GEPs and take advantage of `dso_local_equivalent` for relative references This is useful for the [Relative VTables C++ ABI](https://reviews.llvm.org/D72959) which makes vtables readonly. This works by replacing the dynamic relocations for function pointers in them with static relocations that represent the offset between the vtable and virtual functions. If a function is externally defined, `dso_local_equivalent` can be used as a generic wrapper for the function to still allow for this static offset calculation to be done. See [RFC](http://lists.llvm.org/pipermail/llvm-dev/2020-August/144469.html) for more details. Differential Revision: https://reviews.llvm.org/D77248
100 lines
2.5 KiB
LLVM
100 lines
2.5 KiB
LLVM
; RUN: llc -mtriple=x86_64-linux-gnu -relocation-model=pic -data-sections -o - %s --asm-verbose=0 | FileCheck %s -check-prefixes=CHECK
|
|
|
|
; Just ensure that we can write to an object file without error.
|
|
; RUN: llc -filetype=obj -mtriple=x86_64-linux-gnu -relocation-model=pic -data-sections -o /dev/null %s
|
|
|
|
declare void @extern_func()
|
|
|
|
; CHECK: call_extern_func:
|
|
; CHECK: callq extern_func@PLT
|
|
define void @call_extern_func() {
|
|
call void dso_local_equivalent @extern_func()
|
|
ret void
|
|
}
|
|
|
|
declare hidden void @hidden_func()
|
|
declare protected void @protected_func()
|
|
declare dso_local void @dso_local_func()
|
|
define internal void @internal_func() {
|
|
entry:
|
|
ret void
|
|
}
|
|
define private void @private_func() {
|
|
entry:
|
|
ret void
|
|
}
|
|
|
|
; CHECK: call_hidden_func:
|
|
; CHECK: callq hidden_func{{$}}
|
|
define void @call_hidden_func() {
|
|
call void dso_local_equivalent @hidden_func()
|
|
ret void
|
|
}
|
|
|
|
; CHECK: call_protected_func:
|
|
; CHECK: callq protected_func{{$}}
|
|
define void @call_protected_func() {
|
|
call void dso_local_equivalent @protected_func()
|
|
ret void
|
|
}
|
|
|
|
; CHECK: call_dso_local_func:
|
|
; CHECK: callq dso_local_func{{$}}
|
|
define void @call_dso_local_func() {
|
|
call void dso_local_equivalent @dso_local_func()
|
|
ret void
|
|
}
|
|
|
|
; CHECK: call_internal_func:
|
|
; CHECK: callq internal_func{{$}}
|
|
define void @call_internal_func() {
|
|
call void dso_local_equivalent @internal_func()
|
|
ret void
|
|
}
|
|
|
|
define void @aliasee_func() {
|
|
entry:
|
|
ret void
|
|
}
|
|
|
|
@alias_func = alias void (), void ()* @aliasee_func
|
|
@dso_local_alias_func = dso_local alias void (), void ()* @aliasee_func
|
|
|
|
; CHECK: call_alias_func:
|
|
; CHECK: callq alias_func@PLT
|
|
define void @call_alias_func() {
|
|
call void dso_local_equivalent @alias_func()
|
|
ret void
|
|
}
|
|
|
|
; CHECK: call_dso_local_alias_func:
|
|
; CHECK: callq .Ldso_local_alias_func$local{{$}}
|
|
define void @call_dso_local_alias_func() {
|
|
call void dso_local_equivalent @dso_local_alias_func()
|
|
ret void
|
|
}
|
|
|
|
@ifunc_func = ifunc void (), i64 ()* @resolver
|
|
@dso_local_ifunc_func = dso_local ifunc void (), i64 ()* @resolver
|
|
|
|
define internal i64 @resolver() {
|
|
entry:
|
|
ret i64 0
|
|
}
|
|
|
|
; If an ifunc is not dso_local already, then we should still emit a stub for it
|
|
; to ensure it will be dso_local.
|
|
; CHECK: call_ifunc_func:
|
|
; CHECK: callq ifunc_func@PLT
|
|
define void @call_ifunc_func() {
|
|
call void dso_local_equivalent @ifunc_func()
|
|
ret void
|
|
}
|
|
|
|
; CHECK: call_dso_local_ifunc_func:
|
|
; CHECK: callq dso_local_ifunc_func{{$}}
|
|
define void @call_dso_local_ifunc_func() {
|
|
call void dso_local_equivalent @dso_local_ifunc_func()
|
|
ret void
|
|
}
|