6bbf7f06d8
This adds the basic assembly generation support for the final EH proposal, which was newly adopted in Sep 2023 and advanced into Phase 4 in Jul 2024: https://github.com/WebAssembly/exception-handling/blob/main/proposals/exception-handling/Exceptions.md This adds support for the generation of new `try_table` and `throw_ref` instruction in .s asesmbly format. This does NOT yet include - Block annotation comment generation for .s format - .o object file generation - .s assembly parsing - Type checking (AsmTypeCheck) - Disassembler - Fixing unwind mismatches in CFGStackify These will be added as follow-up PRs. --- The format for `TRY_TABLE`, both for `MachineInstr` and `MCInst`, is as follows: ``` TRY_TABLE type number_of_catches catch_clauses* ``` where `catch_clause` is ``` catch_opcode tag+ destination ``` `catch_opcode` should be one of 0/1/2/3, which denotes `CATCH`/`CATCH_REF`/`CATCH_ALL`/`CATCH_ALL_REF` respectively. (See `BinaryFormat/Wasm.h`) `tag` exists when the catch is one of `CATCH` or `CATCH_REF`. The MIR format is printed as just the list of raw operands. The (stack-based) assembly instruction supports pretty-printing, including printing `catch` clauses by name, in InstPrinter. In addition to the new instructions `TRY_TABLE` and `THROW_REF`, this adds four pseudo instructions: `CATCH`, `CATCH_REF`, `CATCH_ALL`, and `CATCH_ALL_REF`. These are pseudo instructions to simulate block return values of `catch`, `catch_ref`, `catch_all`, `catch_all_ref` clauses in `try_table` respectively, given that we don't support block return values except for one case (`fixEndsAtEndOfFunction` in CFGStackify). These will be omitted when we lower the instructions to `MCInst` at the end. LateEHPrepare now will have one more stage to covert `CATCH`/`CATCH_ALL`s to `CATCH_REF`/`CATCH_ALL_REF`s when there is a `RETHROW` to rethrow its exception. The pass also converts `RETHROW`s into `THROW_REF`. Note that we still use `RETHROW` as an interim pseudo instruction until we convert them to `THROW_REF` in LateEHPrepare. CFGStackify has a new `placeTryTableMarker` function, which places `try_table`/`end_try_table` markers with a necessary `catch` clause and also `block`/`end_block` markers for the destination of the `catch` clause. In MCInstLower, now we need to support one more case for the multivalue block signature (`catch_ref`'s destination's `(i32, exnref)` return type). InstPrinter has a new routine to print the `catch_list` type, which is used to print `try_table` instructions. The new test, `exception.ll`'s source is the same as `exception-legacy.ll`, with the FileCheck expectations changed. One difference is the commands in this file have `-wasm-enable-exnref` to test the new format, and don't have `-wasm-disable-explicit-locals -wasm-keep-registers`, because the new custom InstPrinter routine to print `catch_list` only works for the stack-based instructions (`_S`), and we can't use `-wasm-keep-registers` for them. As in `exception-legacy.ll`, the FileCheck lines for the new tests do not contain the whole program; they mostly contain only the control flow instructions for readability.
209 lines
8.9 KiB
TableGen
209 lines
8.9 KiB
TableGen
//===- WebAssemblyInstrControl.td-WebAssembly control-flow ------*- tablegen -*-
|
|
//
|
|
// Part of the LLVM Project, under the Apache License v2.0 with LLVM Exceptions.
|
|
// See https://llvm.org/LICENSE.txt for license information.
|
|
// SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
|
|
//
|
|
//===----------------------------------------------------------------------===//
|
|
///
|
|
/// \file
|
|
/// WebAssembly control-flow code-gen constructs.
|
|
///
|
|
//===----------------------------------------------------------------------===//
|
|
|
|
let isBranch = 1, isTerminator = 1, hasCtrlDep = 1 in {
|
|
// The condition operand is a boolean value which WebAssembly represents as i32.
|
|
defm BR_IF : I<(outs), (ins bb_op:$dst, I32:$cond),
|
|
(outs), (ins bb_op:$dst),
|
|
[(brcond I32:$cond, bb:$dst)],
|
|
"br_if \t$dst, $cond", "br_if \t$dst", 0x0d>;
|
|
let isCodeGenOnly = 1 in
|
|
defm BR_UNLESS : I<(outs), (ins bb_op:$dst, I32:$cond),
|
|
(outs), (ins bb_op:$dst), []>;
|
|
let isBarrier = 1 in
|
|
defm BR : NRI<(outs), (ins bb_op:$dst),
|
|
[(br bb:$dst)],
|
|
"br \t$dst", 0x0c>;
|
|
} // isBranch = 1, isTerminator = 1, hasCtrlDep = 1
|
|
|
|
def : Pat<(brcond (i32 (setne I32:$cond, 0)), bb:$dst),
|
|
(BR_IF bb_op:$dst, I32:$cond)>;
|
|
def : Pat<(brcond (i32 (seteq I32:$cond, 0)), bb:$dst),
|
|
(BR_UNLESS bb_op:$dst, I32:$cond)>;
|
|
def : Pat<(brcond (i32 (xor bool_node:$cond, (i32 1))), bb:$dst),
|
|
(BR_UNLESS bb_op:$dst, I32:$cond)>;
|
|
|
|
// A list of branch targets enclosed in {} and separated by comma.
|
|
// Used by br_table only.
|
|
def BrListAsmOperand : AsmOperandClass { let Name = "BrList"; }
|
|
let OperandNamespace = "WebAssembly", OperandType = "OPERAND_BRLIST" in
|
|
def brlist : Operand<i32> {
|
|
let ParserMatchClass = BrListAsmOperand;
|
|
let PrintMethod = "printBrList";
|
|
}
|
|
|
|
// Duplicating a BR_TABLE is almost never a good idea. In particular, it can
|
|
// lead to some nasty irreducibility due to tail merging when the br_table is in
|
|
// a loop.
|
|
let isTerminator = 1, hasCtrlDep = 1, isBarrier = 1, isNotDuplicable = 1 in {
|
|
|
|
defm BR_TABLE_I32 : I<(outs), (ins I32:$index, variable_ops),
|
|
(outs), (ins brlist:$brl),
|
|
[(WebAssemblybr_table I32:$index)],
|
|
"br_table \t$index", "br_table \t$brl",
|
|
0x0e>;
|
|
// TODO: SelectionDAG's lowering insists on using a pointer as the index for
|
|
// jump tables, so in practice we don't ever use BR_TABLE_I64 in wasm32 mode
|
|
// currently.
|
|
defm BR_TABLE_I64 : I<(outs), (ins I64:$index, variable_ops),
|
|
(outs), (ins brlist:$brl),
|
|
[(WebAssemblybr_table I64:$index)],
|
|
"br_table \t$index", "br_table \t$brl",
|
|
0x0e>;
|
|
} // isTerminator = 1, hasCtrlDep = 1, isBarrier = 1, isNotDuplicable = 1
|
|
|
|
// This is technically a control-flow instruction, since all it affects is the
|
|
// IP.
|
|
defm NOP : NRI<(outs), (ins), [], "nop", 0x01>;
|
|
|
|
// Placemarkers to indicate the start or end of a block or loop scope.
|
|
// These use/clobber VALUE_STACK to prevent them from being moved into the
|
|
// middle of an expression tree.
|
|
let Uses = [VALUE_STACK], Defs = [VALUE_STACK] in {
|
|
defm BLOCK : NRI<(outs), (ins Signature:$sig), [], "block \t$sig", 0x02>;
|
|
defm LOOP : NRI<(outs), (ins Signature:$sig), [], "loop \t$sig", 0x03>;
|
|
|
|
defm IF : I<(outs), (ins Signature:$sig, I32:$cond),
|
|
(outs), (ins Signature:$sig),
|
|
[], "if \t$sig, $cond", "if \t$sig", 0x04>;
|
|
defm ELSE : NRI<(outs), (ins), [], "else", 0x05>;
|
|
|
|
// END_BLOCK, END_LOOP, END_IF and END_FUNCTION are represented with the same
|
|
// opcode in wasm.
|
|
defm END_BLOCK : NRI<(outs), (ins), [], "end_block", 0x0b>;
|
|
defm END_LOOP : NRI<(outs), (ins), [], "end_loop", 0x0b>;
|
|
defm END_IF : NRI<(outs), (ins), [], "end_if", 0x0b>;
|
|
// Generic instruction, for disassembler.
|
|
let IsCanonical = 1 in
|
|
defm END : NRI<(outs), (ins), [], "end", 0x0b>;
|
|
let isTerminator = 1, isBarrier = 1 in
|
|
defm END_FUNCTION : NRI<(outs), (ins), [], "end_function", 0x0b>;
|
|
} // Uses = [VALUE_STACK], Defs = [VALUE_STACK]
|
|
|
|
|
|
let hasCtrlDep = 1, isBarrier = 1 in {
|
|
let isTerminator = 1 in {
|
|
let isReturn = 1 in {
|
|
|
|
defm RETURN : I<(outs), (ins variable_ops), (outs), (ins),
|
|
[(WebAssemblyreturn)],
|
|
"return", "return", 0x0f>;
|
|
// Equivalent to RETURN, for use at the end of a function when wasm
|
|
// semantics return by falling off the end of the block.
|
|
let isCodeGenOnly = 1 in
|
|
defm FALLTHROUGH_RETURN : I<(outs), (ins variable_ops), (outs), (ins), []>;
|
|
|
|
} // isReturn = 1
|
|
|
|
let IsCanonical = 1, isTrap = 1 in
|
|
defm UNREACHABLE : NRI<(outs), (ins), [(trap)], "unreachable", 0x00>;
|
|
|
|
} // isTerminator = 1
|
|
|
|
// debugtrap explicitly returns despite trapping because it is supposed to just
|
|
// get the attention of the debugger. Unfortunately, because UNREACHABLE is a
|
|
// terminator, lowering debugtrap to UNREACHABLE can create an invalid
|
|
// MachineBasicBlock when there is additional code after it. Lower it to this
|
|
// non-terminator version instead.
|
|
// TODO: Actually execute the debugger statement when running on the Web
|
|
let isTrap = 1 in
|
|
defm DEBUG_UNREACHABLE : NRI<(outs), (ins), [(debugtrap)], "unreachable", 0x00>;
|
|
|
|
} // hasCtrlDep = 1, isBarrier = 1
|
|
|
|
//===----------------------------------------------------------------------===//
|
|
// Exception handling instructions
|
|
//===----------------------------------------------------------------------===//
|
|
|
|
// A list of catch clauses attached to try_table.
|
|
def CatchListAsmOperand : AsmOperandClass { let Name = "CatchList"; }
|
|
let OperandNamespace = "WebAssembly", OperandType = "OPERAND_CATCH_LIST" in
|
|
def catch_list : Operand<i32> {
|
|
let ParserMatchClass = CatchListAsmOperand;
|
|
let PrintMethod = "printCatchList";
|
|
}
|
|
|
|
let Predicates = [HasExceptionHandling] in {
|
|
|
|
// Throwing an exception: throw / throw_ref
|
|
let isTerminator = 1, hasCtrlDep = 1, isBarrier = 1 in {
|
|
defm THROW : I<(outs), (ins tag_op:$tag, variable_ops),
|
|
(outs), (ins tag_op:$tag), [],
|
|
"throw \t$tag", "throw \t$tag", 0x08>;
|
|
defm THROW_REF : I<(outs), (ins EXNREF:$exn), (outs), (ins), [],
|
|
"throw_ref \t$exn", "throw_ref", 0x0a>;
|
|
} // isTerminator = 1, hasCtrlDep = 1, isBarrier = 1
|
|
|
|
// Region within which an exception is caught: try / end_try
|
|
let Uses = [VALUE_STACK], Defs = [VALUE_STACK] in {
|
|
defm TRY_TABLE : I<(outs), (ins Signature:$sig, variable_ops),
|
|
(outs), (ins Signature:$sig, catch_list:$cal), [],
|
|
"try_table \t$sig", "try_table \t$sig $cal", 0x1f>;
|
|
defm END_TRY_TABLE : NRI<(outs), (ins), [], "end_try_table", 0x0b>;
|
|
} // Uses = [VALUE_STACK], Defs = [VALUE_STACK]
|
|
|
|
// Pseudo instructions that represent catch / catch_ref / catch_all /
|
|
// catch_all_ref clauses in a try_table instruction.
|
|
let hasCtrlDep = 1, hasSideEffects = 1, isCodeGenOnly = 1 in {
|
|
let variadicOpsAreDefs = 1 in {
|
|
defm CATCH : I<(outs), (ins tag_op:$tag, variable_ops),
|
|
(outs), (ins tag_op:$tag), []>;
|
|
defm CATCH_REF : I<(outs), (ins tag_op:$tag, variable_ops),
|
|
(outs), (ins tag_op:$tag), []>;
|
|
}
|
|
defm CATCH_ALL : NRI<(outs), (ins), []>;
|
|
defm CATCH_ALL_REF : I<(outs EXNREF:$dst), (ins), (outs), (ins), []>;
|
|
}
|
|
|
|
// Pseudo instructions: cleanupret / catchret
|
|
let isTerminator = 1, hasSideEffects = 1, isBarrier = 1, hasCtrlDep = 1,
|
|
isPseudo = 1, isEHScopeReturn = 1 in {
|
|
defm CLEANUPRET : NRI<(outs), (ins), [(cleanupret)], "cleanupret", 0>;
|
|
defm CATCHRET : NRI<(outs), (ins bb_op:$dst, bb_op:$from),
|
|
[(catchret bb:$dst, bb:$from)], "catchret", 0>;
|
|
} // isTerminator = 1, hasSideEffects = 1, isBarrier = 1, hasCtrlDep = 1,
|
|
// isPseudo = 1, isEHScopeReturn = 1
|
|
|
|
// Below are instructions from the legacy EH proposal. Could be deprecated if
|
|
// usage gets low enough.
|
|
|
|
// Rethrowing an exception: rethrow
|
|
// The new exnref proposal also uses this instruction as an interim pseudo
|
|
// instruction before we convert it to a THROW_REF.
|
|
let isTerminator = 1, hasCtrlDep = 1, isBarrier = 1 in
|
|
defm RETHROW : NRI<(outs), (ins i32imm:$depth), [], "rethrow \t$depth", 0x09>;
|
|
// The depth argument will be computed in CFGStackify. We set it to 0 here for
|
|
// now.
|
|
def : Pat<(int_wasm_rethrow), (RETHROW 0)>;
|
|
|
|
// Region within which an exception is caught: try / end_try
|
|
let Uses = [VALUE_STACK], Defs = [VALUE_STACK] in {
|
|
defm TRY : NRI<(outs), (ins Signature:$sig), [], "try \t$sig", 0x06>;
|
|
defm END_TRY : NRI<(outs), (ins), [], "end_try", 0x0b>;
|
|
} // Uses = [VALUE_STACK], Defs = [VALUE_STACK]
|
|
|
|
// Catching an exception: catch / catch_all
|
|
let hasCtrlDep = 1, hasSideEffects = 1 in {
|
|
let variadicOpsAreDefs = 1 in
|
|
defm CATCH_LEGACY : I<(outs), (ins tag_op:$tag, variable_ops),
|
|
(outs), (ins tag_op:$tag), [],
|
|
"catch", "catch \t$tag", 0x07>;
|
|
defm CATCH_ALL_LEGACY : NRI<(outs), (ins), [], "catch_all", 0x19>;
|
|
}
|
|
|
|
// Delegating an exception: delegate
|
|
let isTerminator = 1, hasCtrlDep = 1, hasSideEffects = 1 in
|
|
defm DELEGATE : NRI<(outs), (ins bb_op:$dst), [], "delegate \t $dst", 0x18>;
|
|
|
|
} // Predicates = [HasExceptionHandling]
|