ace01605e0
This dialect is intended to model lower level/branch based control-flow constructs. The initial set of operations are: AssertOp, BranchOp, CondBranchOp, SwitchOp; all split out from the current standard dialect. See https://discourse.llvm.org/t/standard-dialect-the-final-chapter/6061 Differential Revision: https://reviews.llvm.org/D118966
40 lines
1.5 KiB
MLIR
40 lines
1.5 KiB
MLIR
// RUN: mlir-opt %s \
|
|
// RUN: -gpu-kernel-outlining \
|
|
// RUN: -pass-pipeline='gpu.module(strip-debuginfo,convert-gpu-to-nvvm,gpu-to-cubin)' \
|
|
// RUN: -gpu-to-llvm \
|
|
// RUN: | mlir-cpu-runner \
|
|
// RUN: --shared-libs=%linalg_test_lib_dir/libmlir_cuda_runtime%shlibext \
|
|
// RUN: --shared-libs=%linalg_test_lib_dir/libmlir_runner_utils%shlibext \
|
|
// RUN: --entry-point-result=void \
|
|
// RUN: | FileCheck %s
|
|
|
|
// CHECK: [4, 5, 6, 7, 0, 1, 2, 3, 12, -1, -1, -1, 8]
|
|
func @main() {
|
|
%arg = memref.alloc() : memref<13xf32>
|
|
%dst = memref.cast %arg : memref<13xf32> to memref<?xf32>
|
|
%one = arith.constant 1 : index
|
|
%c0 = arith.constant 0 : index
|
|
%sx = memref.dim %dst, %c0 : memref<?xf32>
|
|
%cast_dst = memref.cast %dst : memref<?xf32> to memref<*xf32>
|
|
gpu.host_register %cast_dst : memref<*xf32>
|
|
gpu.launch blocks(%bx, %by, %bz) in (%grid_x = %one, %grid_y = %one, %grid_z = %one)
|
|
threads(%tx, %ty, %tz) in (%block_x = %sx, %block_y = %one, %block_z = %one) {
|
|
%t0 = arith.index_cast %tx : index to i32
|
|
%val = arith.sitofp %t0 : i32 to f32
|
|
%width = arith.index_cast %block_x : index to i32
|
|
%offset = arith.constant 4 : i32
|
|
%shfl, %valid = gpu.shuffle xor %val, %offset, %width : f32
|
|
cf.cond_br %valid, ^bb1(%shfl : f32), ^bb0
|
|
^bb0:
|
|
%m1 = arith.constant -1.0 : f32
|
|
cf.br ^bb1(%m1 : f32)
|
|
^bb1(%value : f32):
|
|
memref.store %value, %dst[%tx] : memref<?xf32>
|
|
gpu.terminator
|
|
}
|
|
call @print_memref_f32(%cast_dst) : (memref<*xf32>) -> ()
|
|
return
|
|
}
|
|
|
|
func private @print_memref_f32(%ptr : memref<*xf32>)
|