5c02808131
The `opt -analyze` option only works with the legacy pass manager and might be removed in the future, as explained in llvm.org/PR53733. This patch introduced -polly-print-* passes that print what the pass would print with the `-analyze` option and replaces all uses of `-analyze` in the regression tests. There are two exceptions: `CodeGen\single_loop_param_less_equal.ll` and `CodeGen\loop_with_condition_nested.ll` use `-analyze on the `-loops` pass which is not part of Polly. Reviewed By: aeubanks Differential Revision: https://reviews.llvm.org/D120782
48 lines
1.1 KiB
LLVM
48 lines
1.1 KiB
LLVM
; RUN: opt %loadPolly -polly-scops -dot-scops -disable-output < %s
|
|
;
|
|
; Check that the ScopPrinter does not crash.
|
|
; ScopPrinter needs the ScopDetection pass, which should depend on
|
|
; ScalarEvolution transitively.
|
|
|
|
target datalayout = "e-m:e-i64:64-f80:128-n8:16:32:64-S128"
|
|
|
|
define void @func(i32 %n, i32 %m, double* noalias nonnull %A) {
|
|
entry:
|
|
br label %outer.for
|
|
|
|
outer.for:
|
|
%j = phi i32 [0, %entry], [%j.inc, %outer.inc]
|
|
%j.cmp = icmp slt i32 %j, %n
|
|
br i1 %j.cmp, label %inner.for, label %outer.exit
|
|
|
|
inner.for:
|
|
%i = phi i32 [1, %outer.for], [%i.inc, %inner.inc]
|
|
%b = phi double [0.0, %outer.for], [%a, %inner.inc]
|
|
%i.cmp = icmp slt i32 %i, %m
|
|
br i1 %i.cmp, label %body1, label %inner.exit
|
|
|
|
body1:
|
|
%A_idx = getelementptr inbounds double, double* %A, i32 %i
|
|
%a = load double, double* %A_idx
|
|
store double %a, double* %A_idx
|
|
br label %inner.inc
|
|
|
|
inner.inc:
|
|
%i.inc = add nuw nsw i32 %i, 1
|
|
br label %inner.for
|
|
|
|
inner.exit:
|
|
br label %outer.inc
|
|
|
|
outer.inc:
|
|
store double %b, double* %A
|
|
%j.inc = add nuw nsw i32 %j, 1
|
|
br label %outer.for
|
|
|
|
outer.exit:
|
|
br label %return
|
|
|
|
return:
|
|
ret void
|
|
}
|