23e5130ebf
CHANGES SINCE THE ORIGINAL VERSION ---------------------------------- The default test set-up was extracted from * SparseTensor/CPU/lit.local.cfg. and duplicated in all tests. This is to support downstream users that don't use these local LIT config files. SUMMARY OF CHANGES ------------------ This patch aims to reduce test duplication. This is a direct follow-up of: 1. https://reviews.llvm.org/D155403 (test duplication), and 2. https://reviews.llvm.org/D155405 (code re-use), All SVE/VLA tests are now enabled _conditionally_ and refactored to use `mlir-cpu-runner` rather than `lli`. The former helps with test duplication and the latter with code re-use. A few additional refactoring changes are included. 1. The reduce verbosity, long runtime library names like: %mlir_native_utils_lib_dir/libmlir_c_runner_utils%shlibext are replaced with: %mlir_c_runner_utils 2. In order to keep the code and the comments in sync, and to maintain consistency across the tests, the following: enable-runtime-library=true is swapped with (and vice-versa): enable-runtime-library=false Note that this change won't affect test coverage. Only few tests required such update. 3. A VLS vectorization `RUN` line is added in tests where there was a VLA/VLS `RUN` line, but no VLS `RUN` line (with a few exceptions of tests that only contained one `RUN` line to begin with). 4. A few test variables are renamed/added. Most notable example: * %{options}` --> %{sparse_compiler_opts} TEST RUNTIME IMPROVEMENT ------------------------ Tl;Dr This change improves test execution time by ~25%. At the moment, the following `llvm-lit` invocation takes ~7.30s on my AArch64 workstation (with SVE): llvm-lit <llvm-project>/mlir/test/Integration/Dialect/SparseTensor/CPU/ This timing doesn't change no matter what the value of the following CMake variable is (that should disable some tests): MLIR_RUN_ARM_SVE_TESTS With this patch, the execution time will indeed depend on the value of the above CMake variable: * with `MLIR_RUN_ARM_SVE_TESTS=true` the timing remains intact, * with `MLIR_RUN_ARM_SVE_TESTS=false` the timing drops to ~5.40s (~25% improvement). This is expected: * on average there are 4 `RUN` lines per test, * _without this change_ (and with `MLIR_RUN_ARM_SVE_TESTS=false`) the 4th `RUN` line would in most cases duplicate the 3rd `RUN` line, * _with this change) (and with `MLIR_RUN_ARM_SVE_TESTS=false`) the 4th `RUN` line becomes empty. PATCH SIZE ---------- While rather large and touching many files, most changes in this patch are rather mechanical. All test configurations have been preserved and only in a handful of cases new `RUN` lines added. Differential Revision: https://reviews.llvm.org/D156625
93 lines
3.7 KiB
MLIR
93 lines
3.7 KiB
MLIR
//--------------------------------------------------------------------------------------------------
|
|
// WHEN CREATING A NEW TEST, PLEASE JUST COPY & PASTE WITHOUT EDITS.
|
|
//
|
|
// Set-up that's shared across all tests in this directory. In principle, this
|
|
// config could be moved to lit.local.cfg. However, there are downstream users that
|
|
// do not use these LIT config files. Hence why this is kept inline.
|
|
//
|
|
// DEFINE: %{sparse_compiler_opts} = enable-runtime-library=true
|
|
// DEFINE: %{sparse_compiler_opts_sve} = enable-arm-sve=true %{sparse_compiler_opts}
|
|
// DEFINE: %{compile} = mlir-opt %s --sparse-compiler="%{sparse_compiler_opts}"
|
|
// DEFINE: %{compile_sve} = mlir-opt %s --sparse-compiler="%{sparse_compiler_opts_sve}"
|
|
// DEFINE: %{run_libs} = -shared-libs=%mlir_c_runner_utils,%mlir_runner_utils
|
|
// DEFINE: %{run_opts} = -e entry -entry-point-result=void
|
|
// DEFINE: %{run} = mlir-cpu-runner %{run_opts} %{run_libs}
|
|
// DEFINE: %{run_sve} = %mcr_aarch64_cmd --march=aarch64 --mattr="+sve" %{run_opts} %{run_libs}
|
|
//
|
|
// DEFINE: %{env} =
|
|
//--------------------------------------------------------------------------------------------------
|
|
|
|
// RUN: %{compile} | %{run} | FileCheck %s
|
|
//
|
|
// Do the same run, but now with direct IR generation.
|
|
// REDEFINE: %{sparse_compiler_opts} = enable-runtime-library=false
|
|
// RUN: %{compile} | %{run} | FileCheck %s
|
|
//
|
|
// Do the same run, but now with direct IR generation and vectorization.
|
|
// REDEFINE: %{sparse_compiler_opts} = enable-runtime-library=false vl=2 reassociate-fp-reductions=true enable-index-optimizations=true
|
|
// RUN: %{compile} | %{run} | FileCheck %s
|
|
//
|
|
// Do the same run, but now with direct IR generation and VLA vectorization.
|
|
// RUN: %if mlir_arm_sve_tests %{ %{compile_sve} | %{run_sve} | FileCheck %s %}
|
|
|
|
#SparseVector = #sparse_tensor.encoding<{ lvlTypes = [ "compressed" ] }>
|
|
|
|
module {
|
|
|
|
//
|
|
// Sparse kernel.
|
|
//
|
|
func.func @sparse_dot(%a: tensor<1024xf32, #SparseVector>,
|
|
%b: tensor<1024xf32, #SparseVector>,
|
|
%x: tensor<f32>) -> tensor<f32> {
|
|
%dot = linalg.dot ins(%a, %b: tensor<1024xf32, #SparseVector>,
|
|
tensor<1024xf32, #SparseVector>)
|
|
outs(%x: tensor<f32>) -> tensor<f32>
|
|
return %dot : tensor<f32>
|
|
}
|
|
|
|
//
|
|
// Main driver.
|
|
//
|
|
func.func @entry() {
|
|
// Setup two sparse vectors.
|
|
%d1 = arith.constant sparse<
|
|
[ [0], [1], [22], [23], [1022] ], [1.0, 2.0, 3.0, 4.0, 5.0]
|
|
> : tensor<1024xf32>
|
|
%d2 = arith.constant sparse<
|
|
[ [22], [1022], [1023] ], [6.0, 7.0, 8.0]
|
|
> : tensor<1024xf32>
|
|
%s1 = sparse_tensor.convert %d1 : tensor<1024xf32> to tensor<1024xf32, #SparseVector>
|
|
%s2 = sparse_tensor.convert %d2 : tensor<1024xf32> to tensor<1024xf32, #SparseVector>
|
|
|
|
// Call the kernel and verify the output.
|
|
//
|
|
// CHECK: 53
|
|
//
|
|
%t = bufferization.alloc_tensor() : tensor<f32>
|
|
%z = arith.constant 0.0 : f32
|
|
%x = tensor.insert %z into %t[] : tensor<f32>
|
|
%0 = call @sparse_dot(%s1, %s2, %x) : (tensor<1024xf32, #SparseVector>,
|
|
tensor<1024xf32, #SparseVector>,
|
|
tensor<f32>) -> tensor<f32>
|
|
%1 = tensor.extract %0[] : tensor<f32>
|
|
vector.print %1 : f32
|
|
|
|
// Print number of entries in the sparse vectors.
|
|
//
|
|
// CHECK: 5
|
|
// CHECK: 3
|
|
//
|
|
%noe1 = sparse_tensor.number_of_entries %s1 : tensor<1024xf32, #SparseVector>
|
|
%noe2 = sparse_tensor.number_of_entries %s2 : tensor<1024xf32, #SparseVector>
|
|
vector.print %noe1 : index
|
|
vector.print %noe2 : index
|
|
|
|
// Release the resources.
|
|
bufferization.dealloc_tensor %s1 : tensor<1024xf32, #SparseVector>
|
|
bufferization.dealloc_tensor %s2 : tensor<1024xf32, #SparseVector>
|
|
|
|
return
|
|
}
|
|
}
|