15ea016346
BranchProbability now is represented by its numerator and denominator in uint32_t type. This patch changes this representation into a fixed point that is represented by the numerator in uint32_t type and a constant denominator 1<<31. This is quite similar to the representation of BlockMass in BlockFrequencyInfoImpl.h. There are several pros and cons of this change: Pros: 1. It uses only a half space of the current one. 2. Some operations are much faster like plus, subtraction, comparison, and scaling by an integer. Cons: 1. Constructing a probability using arbitrary numerator and denominator needs additional calculations. 2. It is a little less precise than before as we use a fixed denominator. For example, 1 - 1/3 may not be exactly identical to 1 / 3 (this will lead to many BranchProbability unit test failures). This should not matter when we only use it for branch probability. If we use it like a rational value for some precise calculations we may need another construct like ValueRatio. One important reason for this change is that we propose to store branch probabilities instead of edge weights in MachineBasicBlock. We also want clients to use probability instead of weight when adding successors to a MBB. The current BranchProbability has more space which may be a concern. Differential revision: http://reviews.llvm.org/D12603 llvm-svn: 248633
91 lines
3.7 KiB
LLVM
91 lines
3.7 KiB
LLVM
; RUN: opt < %s -sample-profile -sample-profile-file=%S/Inputs/discriminator.prof | opt -analyze -branch-prob | FileCheck %s
|
|
|
|
; Original code
|
|
;
|
|
; 1 int foo(int i) {
|
|
; 2 int x = 0;
|
|
; 3 while (i < 100) {
|
|
; 4 if (i < 5) x--;
|
|
; 5 i++;
|
|
; 6 }
|
|
; 7 return x;
|
|
; 8 }
|
|
;
|
|
; In this test, if the loop is executed 100 times, the decrement operation
|
|
; at line 4 should only execute 5 times. This is reflected in the profile
|
|
; data for line offset 3. In Inputs/discriminator.prof, we have:
|
|
;
|
|
; 3: 100
|
|
; 3.1: 5
|
|
;
|
|
; This means that the predicate 'i < 5' (line 3) is executed 100 times,
|
|
; but the then branch (line 3.1) is only executed 5 times.
|
|
|
|
define i32 @foo(i32 %i) #0 {
|
|
; CHECK: Printing analysis 'Branch Probability Analysis' for function 'foo':
|
|
entry:
|
|
%i.addr = alloca i32, align 4
|
|
%x = alloca i32, align 4
|
|
store i32 %i, i32* %i.addr, align 4
|
|
store i32 0, i32* %x, align 4, !dbg !10
|
|
br label %while.cond, !dbg !11
|
|
|
|
while.cond: ; preds = %if.end, %entry
|
|
%0 = load i32, i32* %i.addr, align 4, !dbg !12
|
|
%cmp = icmp slt i32 %0, 100, !dbg !12
|
|
br i1 %cmp, label %while.body, label %while.end, !dbg !12
|
|
; CHECK: edge while.cond -> while.body probability is 0x7ebb907a / 0x80000000 = 99.01% [HOT edge]
|
|
; CHECK: edge while.cond -> while.end probability is 0x01446f86 / 0x80000000 = 0.99%
|
|
|
|
while.body: ; preds = %while.cond
|
|
%1 = load i32, i32* %i.addr, align 4, !dbg !14
|
|
%cmp1 = icmp slt i32 %1, 50, !dbg !14
|
|
br i1 %cmp1, label %if.then, label %if.end, !dbg !14
|
|
; CHECK: edge while.body -> if.then probability is 0x06666666 / 0x80000000 = 5.00%
|
|
; CHECK: edge while.body -> if.end probability is 0x7999999a / 0x80000000 = 95.00% [HOT edge]
|
|
|
|
if.then: ; preds = %while.body
|
|
%2 = load i32, i32* %x, align 4, !dbg !17
|
|
%dec = add nsw i32 %2, -1, !dbg !17
|
|
store i32 %dec, i32* %x, align 4, !dbg !17
|
|
br label %if.end, !dbg !17
|
|
|
|
if.end: ; preds = %if.then, %while.body
|
|
%3 = load i32, i32* %i.addr, align 4, !dbg !19
|
|
%inc = add nsw i32 %3, 1, !dbg !19
|
|
store i32 %inc, i32* %i.addr, align 4, !dbg !19
|
|
br label %while.cond, !dbg !20
|
|
|
|
while.end: ; preds = %while.cond
|
|
%4 = load i32, i32* %x, align 4, !dbg !21
|
|
ret i32 %4, !dbg !21
|
|
}
|
|
|
|
|
|
!llvm.dbg.cu = !{!0}
|
|
!llvm.module.flags = !{!7, !8}
|
|
!llvm.ident = !{!9}
|
|
|
|
!0 = distinct !DICompileUnit(language: DW_LANG_C99, producer: "clang version 3.5 ", isOptimized: false, emissionKind: 0, file: !1, enums: !2, retainedTypes: !2, subprograms: !3, globals: !2, imports: !2)
|
|
!1 = !DIFile(filename: "discriminator.c", directory: ".")
|
|
!2 = !{}
|
|
!3 = !{!4}
|
|
!4 = distinct !DISubprogram(name: "foo", line: 1, isLocal: false, isDefinition: true, virtualIndex: 6, flags: DIFlagPrototyped, isOptimized: false, scopeLine: 1, file: !1, scope: !5, type: !6, function: i32 (i32)* @foo, variables: !2)
|
|
!5 = !DIFile(filename: "discriminator.c", directory: ".")
|
|
!6 = !DISubroutineType(types: !2)
|
|
!7 = !{i32 2, !"Dwarf Version", i32 4}
|
|
!8 = !{i32 1, !"Debug Info Version", i32 3}
|
|
!9 = !{!"clang version 3.5 "}
|
|
!10 = !DILocation(line: 2, scope: !4)
|
|
!11 = !DILocation(line: 3, scope: !4)
|
|
!12 = !DILocation(line: 3, scope: !13)
|
|
!13 = !DILexicalBlockFile(discriminator: 1, file: !1, scope: !4)
|
|
!14 = !DILocation(line: 4, scope: !15)
|
|
!15 = distinct !DILexicalBlock(line: 4, column: 0, file: !1, scope: !16)
|
|
!16 = distinct !DILexicalBlock(line: 3, column: 0, file: !1, scope: !4)
|
|
!17 = !DILocation(line: 4, scope: !18)
|
|
!18 = !DILexicalBlockFile(discriminator: 1, file: !1, scope: !15)
|
|
!19 = !DILocation(line: 5, scope: !16)
|
|
!20 = !DILocation(line: 6, scope: !16)
|
|
!21 = !DILocation(line: 7, scope: !4)
|