57b08b0944
to reflect the new license. These used slightly different spellings that defeated my regular expressions. We understand that people may be surprised that we're moving the header entirely to discuss the new license. We checked this carefully with the Foundation's lawyer and we believe this is the correct approach. Essentially, all code in the project is now made available by the LLVM project under our new license, so you will see that the license headers include that license only. Some of our contributors have contributed code under our old license, and accordingly, we have retained a copy of our old license notice in the top-level files in each project and repository. llvm-svn: 351648
52 lines
1.3 KiB
ArmAsm
52 lines
1.3 KiB
ArmAsm
//===-- floatundidf.S - Implement __floatundidf for x86_64 ----------------===//
|
|
//
|
|
// Part of the LLVM Project, under the Apache License v2.0 with LLVM Exceptions.
|
|
// See https://llvm.org/LICENSE.txt for license information.
|
|
// SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
|
|
//
|
|
//===----------------------------------------------------------------------===//
|
|
//
|
|
// This file implements __floatundidf for the compiler_rt library.
|
|
//
|
|
//===----------------------------------------------------------------------===//
|
|
|
|
#include "../assembly.h"
|
|
|
|
// double __floatundidf(du_int a);
|
|
|
|
#ifdef __x86_64__
|
|
|
|
CONST_SECTION
|
|
|
|
.balign 16
|
|
twop52:
|
|
.quad 0x4330000000000000
|
|
|
|
.balign 16
|
|
twop84_plus_twop52:
|
|
.quad 0x4530000000100000
|
|
|
|
.balign 16
|
|
twop84:
|
|
.quad 0x4530000000000000
|
|
|
|
#define REL_ADDR(_a) (_a)(%rip)
|
|
|
|
.text
|
|
.balign 4
|
|
DEFINE_COMPILERRT_FUNCTION(__floatundidf)
|
|
movd %edi, %xmm0 // low 32 bits of a
|
|
shrq $32, %rdi // high 32 bits of a
|
|
orq REL_ADDR(twop84), %rdi // 0x1p84 + a_hi (no rounding occurs)
|
|
orpd REL_ADDR(twop52), %xmm0 // 0x1p52 + a_lo (no rounding occurs)
|
|
movd %rdi, %xmm1
|
|
subsd REL_ADDR(twop84_plus_twop52), %xmm1 // a_hi - 0x1p52 (no rounding occurs)
|
|
addsd %xmm1, %xmm0 // a_hi + a_lo (round happens here)
|
|
ret
|
|
END_COMPILERRT_FUNCTION(__floatundidf)
|
|
|
|
#endif // __x86_64__
|
|
|
|
NO_EXEC_STACK_DIRECTIVE
|
|
|