cb9f78e1c3
There was an efficiency problem with how we processed @llvm.assume in ValueTracking (and other places). The AssumptionCache tracked all of the assumptions in a given function. In order to find assumptions relevant to computing known bits, etc. we searched every assumption in the function. For ValueTracking, that means that we did O(#assumes * #values) work in InstCombine and other passes (with a constant factor that can be quite large because we'd repeat this search at every level of recursion of the analysis). Several of us discussed this situation at the last developers' meeting, and this implements the discussed solution: Make the values that an assume might affect operands of the assume itself. To avoid exposing this detail to frontends and passes that need not worry about it, I've used the new operand-bundle feature to add these extra call "operands" in a way that does not affect the intrinsic's signature. I think this solution is relatively clean. InstCombine adds these extra operands based on what ValueTracking, LVI, etc. will need and then those passes need only search the users of the values under consideration. This should fix the computational-complexity problem. At this point, no passes depend on the AssumptionCache, and so I'll remove that as a follow-up change. Differential Revision: https://reviews.llvm.org/D27259 llvm-svn: 289755
69 lines
1.9 KiB
LLVM
69 lines
1.9 KiB
LLVM
; RUN: opt -S -jump-threading -dce < %s | FileCheck %s
|
|
target datalayout = "e-m:e-i64:64-f80:128-n8:16:32:64-S128"
|
|
target triple = "x86_64-unknown-linux-gnu"
|
|
|
|
; Function Attrs: nounwind uwtable
|
|
define i32 @test1(i32 %a, i32 %b) #0 {
|
|
entry:
|
|
%cmp = icmp sgt i32 %a, 5
|
|
tail call void @llvm.assume(i1 %cmp) [ "affected"(i32 %a) ]
|
|
%cmp1 = icmp sgt i32 %b, 1234
|
|
br i1 %cmp1, label %if.then, label %if.else
|
|
|
|
; CHECK-LABEL: @test1
|
|
; CHECK: icmp sgt i32 %a, 5
|
|
; CHECK: call void @llvm.assume
|
|
; CHECK-NOT: icmp sgt i32 %a, 3
|
|
; CHECK: ret i32
|
|
|
|
if.then: ; preds = %entry
|
|
%cmp2 = icmp sgt i32 %a, 3
|
|
br i1 %cmp2, label %if.then3, label %return
|
|
|
|
if.then3: ; preds = %if.then
|
|
tail call void (...) @bar() #1
|
|
br label %return
|
|
|
|
if.else: ; preds = %entry
|
|
tail call void (...) @car() #1
|
|
br label %return
|
|
|
|
return: ; preds = %if.else, %if.then, %if.then3
|
|
%retval.0 = phi i32 [ 1, %if.then3 ], [ 0, %if.then ], [ 0, %if.else ]
|
|
ret i32 %retval.0
|
|
}
|
|
|
|
define i32 @test2(i32 %a) #0 {
|
|
entry:
|
|
%cmp = icmp sgt i32 %a, 5
|
|
tail call void @llvm.assume(i1 %cmp) [ "affected"(i32 %a) ]
|
|
%cmp1 = icmp sgt i32 %a, 3
|
|
br i1 %cmp1, label %if.then, label %return
|
|
|
|
; CHECK-LABEL: @test2
|
|
; CHECK: icmp sgt i32 %a, 5
|
|
; CHECK: tail call void @llvm.assume
|
|
; CHECK: tail call void (...) @bar()
|
|
; CHECK: ret i32 1
|
|
|
|
|
|
if.then: ; preds = %entry
|
|
tail call void (...) @bar() #1
|
|
br label %return
|
|
|
|
return: ; preds = %entry, %if.then
|
|
%retval.0 = phi i32 [ 1, %if.then ], [ 0, %entry ]
|
|
ret i32 %retval.0
|
|
}
|
|
|
|
; Function Attrs: nounwind
|
|
declare void @llvm.assume(i1) #1
|
|
|
|
declare void @bar(...)
|
|
|
|
declare void @car(...)
|
|
|
|
attributes #0 = { nounwind uwtable }
|
|
attributes #1 = { nounwind }
|
|
|