0f46e31cfb
As part of the migration to ptradd (https://discourse.llvm.org/t/rfc-replacing-getelementptr-with-ptradd/68699), we need to change the representation of the `inrange` attribute, which is used for vtable splitting. Currently, inrange is specified as follows: ``` getelementptr inbounds ({ [4 x ptr], [4 x ptr] }, ptr @vt, i64 0, inrange i32 1, i64 2) ``` The `inrange` is placed on a GEP index, and all accesses must be "in range" of that index. The new representation is as follows: ``` getelementptr inbounds inrange(-16, 16) ({ [4 x ptr], [4 x ptr] }, ptr @vt, i64 0, i32 1, i64 2) ``` This specifies which offsets are "in range" of the GEP result. The new representation will continue working when canonicalizing to ptradd representation: ``` getelementptr inbounds inrange(-16, 16) (i8, ptr @vt, i64 48) ``` The inrange offsets are relative to the return value of the GEP. An alternative design could make them relative to the source pointer instead. The result-relative format was chosen on the off-chance that we want to extend support to non-constant GEPs in the future, in which case this variant is more expressive. This implementation "upgrades" the old inrange representation in bitcode by simply dropping it. This is a very niche feature, and I don't think trying to upgrade it is worthwhile. Let me know if you disagree.
56 lines
2.2 KiB
LLVM
56 lines
2.2 KiB
LLVM
; RUN: opt < %s -passes=globaldce -S | FileCheck %s
|
|
|
|
target datalayout = "e-m:e-i64:64-f80:128-n8:16:32:64-S128"
|
|
|
|
declare dso_local noalias nonnull ptr @_Znwm(i64)
|
|
declare { ptr, i1 } @llvm.type.checked.load(ptr, i32, metadata)
|
|
|
|
; %struct.A is a C++ struct with two virtual functions, A::foo and A::bar. The
|
|
; !vcall_visibility metadata is set on the vtable, so we know that all virtual
|
|
; calls through this vtable are visible and use the @llvm.type.checked.load
|
|
; intrinsic. Function test_A makes a call to A::foo, but there is no call to
|
|
; A::bar anywhere, so A::bar can be deleted, and its vtable slot replaced with
|
|
; null.
|
|
|
|
%struct.A = type { ptr }
|
|
|
|
; The pointer to A::bar in the vtable can be removed, because it will never be
|
|
; loaded. We replace it with null to keep the layout the same. Because it is at
|
|
; the end of the vtable we could potentially shrink the vtable, but don't
|
|
; currently do that.
|
|
; CHECK: @_ZTV1A = internal unnamed_addr constant { [4 x ptr] } { [4 x ptr] [ptr null, ptr null, ptr @_ZN1A3fooEv, ptr null] }
|
|
@_ZTV1A = internal unnamed_addr constant { [4 x ptr] } { [4 x ptr] [ptr null, ptr null, ptr @_ZN1A3fooEv, ptr @_ZN1A3barEv] }, align 8, !type !0, !type !1, !type !2, !vcall_visibility !3
|
|
|
|
; A::foo is called, so must be retained.
|
|
; CHECK: define internal i32 @_ZN1A3fooEv(
|
|
define internal i32 @_ZN1A3fooEv(ptr nocapture readnone %this) {
|
|
entry:
|
|
ret i32 42
|
|
}
|
|
|
|
; A::bar is not used, so can be deleted.
|
|
; CHECK-NOT: define internal i32 @_ZN1A3barEv(
|
|
define internal i32 @_ZN1A3barEv(ptr nocapture readnone %this) {
|
|
entry:
|
|
ret i32 1337
|
|
}
|
|
|
|
define dso_local i32 @test_A() {
|
|
entry:
|
|
%call = tail call ptr @_Znwm(i64 8)
|
|
store ptr getelementptr inbounds inrange(-16, 16) ({ [4 x ptr] }, ptr @_ZTV1A, i64 0, i32 0, i64 2), ptr %call, align 8
|
|
%0 = tail call { ptr, i1 } @llvm.type.checked.load(ptr getelementptr inbounds inrange(-16, 16) ({ [4 x ptr] }, ptr @_ZTV1A, i64 0, i32 0, i64 2), i32 0, metadata !"_ZTS1A"), !nosanitize !9
|
|
%1 = extractvalue { ptr, i1 } %0, 0, !nosanitize !9
|
|
%call1 = tail call i32 %1(ptr nonnull %call)
|
|
ret i32 %call1
|
|
}
|
|
|
|
!llvm.module.flags = !{!4}
|
|
|
|
!0 = !{i64 16, !"_ZTS1A"}
|
|
!1 = !{i64 16, !"_ZTSM1AFivE.virtual"}
|
|
!2 = !{i64 24, !"_ZTSM1AFivE.virtual"}
|
|
!3 = !{i64 2}
|
|
!4 = !{i32 1, !"Virtual Function Elim", i32 1}
|
|
!9 = !{}
|